系统函数

begin()

機能です:

LCDの初期化; SDカードの初期化; シリアルポートバッファをクリア、シリアルポートのボーレートを115200に設定; I2Cの初期化; MBusモードの設定; Axp電源管理チップの初期化; タッチスクリーンの初期化; RTCの初期化

原型関数です:

void begin(bool LCDEnable = true, bool SDEnable = true, bool SerialEnable = true, bool I2CEnable = false, mbus_mode_t mode = kMBusModeOutput)

関数実装です:

void M5Core2::begin(bool LCDEnable, bool SDEnable, bool SerialEnable, bool I2CEnable, mbus_mode_t mode) {
  // Correct init once
  if (isInited == true) {
    return;
  } else {
    isInited = true;
  }

  // UART
  if (SerialEnable == true) {
    Serial.begin(115200);
    Serial.flush();
    delay(50);
    Serial.print("M5Core2 initializing...");
  }

  // I2C init
  if (I2CEnable == true) {
    Wire.begin(32, 33);
  }

  Axp.begin(mode);

  // LCD INIT
  if (LCDEnable == true) {
    Lcd.begin();
  }

  // Touch init
  Touch.begin();  // Touch begin after AXP begin. (Reset at the start of AXP)

  // TF Card
  if (SDEnable == true) {
    SD.begin(TFCARD_CS_PIN, SPI, 40000000);
  }

  // TONE
  if (SerialEnable == true) {
    Serial.println("OK");
  }

  Rtc.begin();
}

使用例です:

#include <M5Core2.h>

void setup() {
  M5.begin();
}

update()

機能です:

ボタンの状態を読み取る

原型関数です:

void update()

関数実装です:

void M5Core2::update() {
  Touch.update();
  Buttons.update();
  yield();
}

使用例です:

#include <M5Core2.h>

void setup() {
  M5.begin();
}

void loop() {
  M5.update();
}

shutdown()

関数オーバーロードです1:

電源を切断、再起動にはPWRボタンを押下する必要がある

void shutdown()

関数オーバーロードです2:

電源を切断、指定の秒数の遅延後、RTCを通じてデバイスを起動する

int shutdown( int seconds )

関数オーバーロードです3:

電源を切断、RTCの時間構造体で指定の時刻に、時、分、秒が一致した時、RTCを通じてデバイスを起動する

int shutdown( const RTC_TimeTypeDef &RTC_TimeStruct)

関数オーバーロードです4:

電源を切断、RTCの日付と時間構造体で指定の日付と時刻に、週数、日数、時刻が一致した時、RTCを通じてデバイスを起動する

int shutdown( const RTC_DateTypeDef &RTC_DateStruct, const RTC_TimeTypeDef &RTC_TimeStruct)

使用例です:

#include <M5Core2.h>

RTC_TimeTypeDef RTCtime;
RTC_TimeTypeDef RTCtime_Now;

char timeStrbuff[64];

void setup(){
  M5.begin(true,true,true,true);

  RTCtime.Hours = 10;
  RTCtime.Minutes = 30;
  RTCtime.Seconds = 45;

  M5.Lcd.setCursor(0,80);
  M5.Lcd.println("");
  M5.Lcd.println("BtnA:  shutdown, use power button to turn back on");
  M5.Lcd.println("");
  M5.Lcd.println("BtnB:  shutdown, wake up after 5 seconds");
  M5.Lcd.println("");
  M5.Lcd.println("BtnC:  shutdown, wake up at RTC Time 10:30:45");
}

void loop(){
  M5.update();
  if(M5.BtnA.wasPressed()){
    M5.shutdown();
  }else if(M5.BtnB.wasPressed()){
    M5.shutdown(5);
  }else if(M5.BtnC.wasPressed()){
    M5.shutdown(RTCtime);
  }

  M5.Lcd.setCursor(0,140);
  M5.Rtc.GetTime(&RTCtime_Now);
  sprintf(timeStrbuff,"RTC Time Now is %02d:%02d:%02d",
         RTCtime_Now.Hours,RTCtime_Now.Minutes,RTCtime_Now.Seconds);
  M5.Lcd.println(timeStrbuff);
}